I put on my engineering hat and dissected spam emails to find out where the stuff was coming from. I also posted my findings in an open letter to VistaPrint end of March 2004.
Nothing happened for a while and then, out of the blue, an employee from VistaPrint responded and offered to look into the issue. I sent a number of spam samples, which I still happened to have lying around, to that person and, surprise, surprise, never received a response from anybody at VistaPrint (most likely those forwarded spam messages along with my comments were filed under junk mail as well).

If I can trust the traffic analysis for kahunaburger, that very same VistaPrint open letter above is one of the busiest pages on my server. Just in the last few weeks it received at least 10 comments from people who suffer under the constant spam bombardment or who have been duped into signing up for something that they don’t want. Searching for “vistaprint spam” on Google, shows that kahunaburger is listed as the very first entry.

I have little hope that any of those actions mentioned in the comments to the open letter will make any difference. VistaPrint, with headquarters in the Bermudas, lives from affiliate networks driving traffic to their site. Those affiliate networks have been linked to spam since the beginning of spam. VistaPrint claims that they don’t allow affiliate members to send unsolicited emails, but they don’t do anything about it proactively, but instead just pretend to investigate whenever too many people complain about a particular spam incident. Even if they sack the responsible affiliate and terminate his account, that guy just turns around and signs up under a different name/email to do the very same again.

Just take a look at all the information that’s posted about VistaPrint on ripoffreport.com – makes you really wonder how they can still be in business.

Anyway, what I found interesting was the fact that a 5-year old post on this site could still generate substantial traffic today …

Looks like somebody discovered that “banner” (if you’re on a Unix system try this from a shell: banner “foo”) with a small font-size yields machine-unreadable but human-readable content. Almost a reverse-captcha, let’s call it raptcha …

localhost$ grep "69.50.182.154" access_log | wc -l

303

localhost$


(that’s since this morning 2am). And:

localhost$ zcat access_log.1.gz| grep "69.50.182.154" | wc -l

1398

localhost$


(that would be last week)

So Emil has earned himself already a permanent place in my heart for providing an open proxy to the world, but I can’t believe that nobody else is being targeted – or are you being bugged by “69.50.182.154″ as well?

“So Sam, like other link spammers, uses the thousands of ‘open proxies’ on the net. These are machines which, by accident (read: clueless sysadmins) or design (read: clueless managers) are set up so that anyone, anywhere, can access another website through them. Usually intended for internal use, so a company only needs one machine facing the net, they’re actually hard to lock down completely.”

This validates mt-proxyplug as a means to get rid of comment spam. Since I have it running on my web site I had to deal with only a few comment spam submissions here.

Also, Sixapart’s Professional Network seems to have picked up the story and issues recommendations on how to avoid the problem.

It was a close race between the two favorites and only a few hundred referer spam entries separate them, but in the end, there can only be one winner.

We analyzed our Apache server logs from the last few weeks and looked up all log entries that show “referer” information. Here’s a sample line from the logs that shows the free-online-texas-holdem.fidelityfunding.net site refering to an entry on kahunaburger.com:

82.194.62.16 - - [17/Jan/2005:09:21:26 -0700] "GET /blog/archives/000113.html HTTP/1.1" 200 10196 "http://free-online-texas-holdem.fidelityfunding.net/" "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.2; .NET CL
R 1.1.4322)"

Of course, nobobdy on fidelityfunding.net knows that kahunaburger.com even exists, but that’s a different story.

Anyway, we extracted similar lines from the log-files and looked up the ip-address for the host that refered our site. In this case the ip-address for free-online-texas-holdem.fidelityfunding.net would be 219.150.118.16.
We counted how often a certain ip-address refered to us and what hostname was used in the referal process.

To make it short, there’s only a first and a second place. First place goes to 64.234.220.141 with 1621 referer spam entries and second place goes to 219.150.118.16 with 1315 referer spam entries.

Congratulations to the winners! You really make the web a better place with all the useful advice you offer for free! Keep up the good work! And hopefully we’ll see some other people join the competition for next months awards?!

The detailed findings, in case you are still interested:

How it all started

I am a longtime user of Jay Allen’s Blacklist and was happy with it for a long time. Recently I could not keep up with adding new keywords/urls to the black list. There seem to be a million variations of “Texas Hold’em” out there and I ended up adding those items slowly to the Blacklist system (in the end I actually added “texas” as a Blacklist item only to find a “texa$ H0ld’em” the next day in my list of moderated comments).

I started to look more carefully at the offending posts and investigated the submitting IP addresses in detail. Soon I realized that most of the stuff was coming from public proxy servers. Companies stupid enough to run public proxies and hijacked user systems are on top of the list of systems that submitted spam to my server.

Monitoring the proxies

My apache configuration was changed to include some proxy specific information in my access_logs. I changed the line:
LogFormat "%h %l %u %t "%r" %>s %b "%{Referer}i" "%{User-Agent}i"" combined
to
LogFormat "%h %l %u %t "%r" %>s %b "%{Referer}i" "%{User-Agent}i" %{HTTP_X_FORWARDED_FOR}e" combined

This means that the apache server will also log the contents of the environment variable “HTTP_X_FORWARDED_FOR” to the access_log, whenever that environment variable is present. And the environment variable is present if the current request contains a “X-Forwarded-For:” header item. The presence of this item is almost always a clear indication that the request was handled by a proxy server. Items that would have previously been logged like this:

200.242.249.70 - - [15/Jan/2005:11:31:52 -0700] "POST /blog/mt-comments.cgi HTTP/1.0" 302 0 "http://www.kahunaburger.com/blog/mt-comments.cgi?entry_id=113" "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.2; .NET CLR 1.1.4322)"

suddenly looked like this:

200.242.249.70 - - [15/Jan/2005:11:31:52 -0700] "POST /blog/mt-comments.cgi HTTP/1.0" 302 0 "http://www.kahunaburger.com/blog/mt-comments.cgi?entry_id=113" "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.2; .NET CLR 1.1.4322)" 168.41.192.0

(note the addition of the IP address at the end of the line)

That’s when I started focusing on proxies and developed mt-commentproxyblock, which evolved into mt-proxyplug.

What does it do?

mt-proxyplug when installed on a MovableType system will act as a ‘CommentFilter’. Every comment submission is passed through it, before it is committed to the database. The plugin will inspect the remote IP address of the system that submits the comment. First it will check if there is a “X-Forwarded-For:” header item in the current comment submission request. The mere presence of the header field is an indication that stuff is being submitted through a proxy server. It will then query the Distributed Sender Blackhole List and the Blitzed Open Proxy Monitor List for entries for the submitting remote IP address. If either one knows about the IP address, then we assume that the comment comes from a known public proxy system.

In a last test the remote system is probed on a number of common proxy ports. We try to get access through the system to a well-known and relatively stable host on the internet. If this request is processed successfully on any of the probed ports we also assume that the remote end is indeed a public proxy.

If any one of the above tests is positive we are not executing the other tests and simply flag the current comment submission as suspicious.

A configuration section at the top of the file allows for customization of the list of tests the plugin should run.
There is also a CACHE_COUNT definition that specifies how many found proxies the plugin should keep track of (this will make it much quicker on subsequent requests, if a proxy is used numerous times in a row).

A log of the plugin’s actions is also provided in MT’s Activity Log. Here’s just a small section from my current log:

Since I installed the plugin on kahunaburger.com’s blog it has caught 121 of 122 comment submissions. The one that slipped through was actually caught by mt-spamassassin. During the same time period I also received 4 good comment submissions which made it through the system without any problems.

How to use mt-proxyplug

Just drop the file below into your MovableType’s plugins folder. Modify the “settings” section to your liking (the default values are the recommended values) and you’re set.
No other modules are required (I assume that IO::Socket is available on all newer perl installations). HTTP::CheckProxy (as used in the previous version of the plugin) has been dropped, because it would report false positives (or is it “true negatives”?).

Update 01/20/2005: I’ve updated the plugin below to version 0.6. Two changes since the original version:
1) I set CHECK_LIST_DSBL_ORG to “0″ by default, based on ioerror.us’s comments here
2) I fixed the require list at the top of the file to include “LWP::UserAgent” after receiving a problem report from Chris.

You can download the plugin here: mt-proxyplug.pl.gz (2.5KB, gzip)

Along the same lines as yesterday’s SpamAssassin and MovableType entry, here’s another weapon against the “texas hold’em” and “football–betting” idiots.

Those morons have a tendency to conceal their identity. They are hiding behind public proxy servers and bombard your servers with their crap from there. So all we have to do is to check for a public proxy when somebody tries to submit a comment. If I detect a submission through a public proxy server it will not end up on the site, but will be ignored silently.

The proxy check is done in two stages:

• if we find the HTTP_X_FORWARDED_FOR environment variable we assume that a proxy has handled the request and we don’t even look any further.
• if no HTTP_X_FORWARDED_FOR is found, we grab Apache’s REMOTE_ADDR environment variable (the ip-address of the system who sent the current request) and use the HTTP::CheckProxy module to test whether the submitting system is a public proxy server

If a comment submission is coming from a public proxy we drop a line in the server’s error_log. Here are just some of the entries I captured since I installed it:

[Thu Jan 13 08:35:21 2005] comment denied - using proxy: 216.49.49.118 80.25.156.151 -
poker/bushmills1614@rocketmail.com/80.58.4.111
[Thu Jan 13 08:35:46 2005] comment denied - using proxy: 24.215.40.47 -
football betting/bob@y6322o.com/63.110.140.28
[Thu Jan 13 08:39:00 2005] comment denied - using proxy: 58.40.89.127 -
phentermine/gocha9985@see.it/203.199.92.158
[Thu Jan 13 08:48:59 2005] comment denied - using proxy: 115.120.174.78, 127.0.0.1 -
online poker/absolut5129@freemail.com/80.255.49.222

And before somebody points me at Brad’s DBSL plugin: I’ve tested all the proxies listed above and they do not appear in the DSBL.

In order to use the plugin you will need to have the perl module HTTP::CheckProxy on your system. Drop the perl-code below into your MT plugins folder and you should be ready to go. Again, this has only been tested under Apache!

You can download the compressed version here: mt-commentproxyblock.pl.gz (1 Kb,gzip)

#!/usr/bin/perl -w
package MT::Plugin::CommentProxyBlock;
use strict;
use lib '../lib';
use vars qw ($VERSION);
$VERSION='0.2';
use constant ACCEPT_RESPONSE => 1;
use constant DENY_RESPONSE   => 0;
use MT;
use MT::App::Comments;
use HTTP::CheckProxy;
eval{ require MT::Plugin };
unless ($@) {
    my $plugin = {
        name => qq{Comment Proxy Block for Movable Type v$VERSION},
        description => qq{Will block attempts to post a comment via a proxy server},
    };
    MT->add_plugin(new MT::Plugin($plugin));
    # tell MT that we want to be called to filter comments
    MT->add_callback('CommentFilter', 1, $plugin, \&proxyCheck_filter);
}
# proxyCheck_filter
#
# checks environment for an entry which indicates we are handling a request that
# came from a proxy server (HTTP_X_FORWARDED_FOR). If environment does not give
# any indication, check REMOTE_ADDR and see if it proxies requests for us. If
# either is true we deny the comment posting attempt. Tested in Apache only!
sub proxyCheck_filter {
    my($eh,$app,$comment)=@_;
    my($isProxy,$proxy)=(0,'');
    # uncomment to get a complete dump of the environment
    # dumpEnv();
    # check environment
    $proxy=$ENV{HTTP_X_FORWARDED_FOR};
    if(defined($proxy) && length($proxy)) {
        print STDERR "[".scalar(localtime())."] proxy request forwarded for: $proxy\n";
        # if we have a X-Forwarded-For header, it was most likely
        # added by the system that sent the request
        $proxy=$ENV{REMOTE_ADDR};
        $isProxy++;
    }
    # check remote address
    unless($isProxy) {
        $proxy=$ENV{REMOTE_ADDR};
        print STDERR "[".scalar(localtime())."] probing for open proxy: $proxy\n";
        my $p=HTTP::CheckProxy->new($proxy,qq{http://www.google.com/});
        $isProxy++ if($p->guilty());
    }
    if($isProxy) {
        print STDERR "[".scalar(localtime())."] comment denied - " .
          "using proxy: $proxy - " .
          join("/",$comment->author,$comment->email,$comment->ip) .
          "\n";
        return DENY_RESPONSE;
    }
    return ACCEPT_RESPONSE;
}
sub dumpEnv {
    print STDERR "[".scalar(localtime())."] environment for $0:\n";
    foreach my $key (sort keys %ENV) {
        print STDERR "[".scalar(localtime())."]   $key = ",$ENV{$key},"\n";
    }
}
1;

A few days ago I saw the post on ioerror.us which details a solution to link WordPress’s comment checking system with Spam Assassin. I run MovableType and a WordPress solution does not work for me. The code needed to change a bit before it was usable on my system.

After enabling it last night and disabling mt-blacklist, I’m happy to report that it has caught every single comment spam attempt (a total of 32 attempts were registered). Spam indications appear in my server’s error_log like this:

[Tue Jan 11 08:33:34 2005] spam from diet pills/jane_doe7082@work.com/
148.244.150.58: score 10.7 (limit 5.0)

A message like this indicates that the ‘CommentFilter’ implemented in mt-spamassassin.pl has received notification from the Spam Assassin daemon that the current comment is over the Spam Assassin threshold.

In order to use the mt-spamassassin.pl plugin you will need to have Spam Assassin’s spamd running on your own network or need access to spamd running on a remote system. Enter the name of the system that runs spamd in $sa_spamd_host (use ‘localhost’ if it’s running on the same host as MovableType) and also enter the port number where spamd can be reached in $sa_spamd_port. And because I did not find a way to retrieve a blog owners email address from within the MoveableType plugin, please also enter your email address in $mt_owner. For SpamAssassin’s user_prefs to work, you should also set your real (unix) userid in $mt_userid. Drop the modified file in your blog’s plugins folder and it should be ready to go.

Thanks to http://www.ioerror.us/ for the cool idea!

You can download the compressed version here: mt-spamassassin.pl.gz (1.5 Kb,gzip)

Update 01/14/2005: I’ve since added another plugin called mt-commentproxyblock, which has detected every single spam submission on 01/13/2005 before it was passed through mt-spamassassin. It seems that the majority of spammers do use public proxies and those are easy to detect.

Update 01/20/2005: I just posed a new version of the plugin with a few enhancements. If you have both mt-spamassassin and mt-proxyplug on your system, a comment will be shortcut if mt-proxyplug has already determined that it comes from an open proxy. Specifically, mt-spamassassin will look at the visible-flag of the comment and will not work on comments which are not visible. This will cut down on processing time for spam comments.
Second, Justin was nice enough to correct the fake Message-header I’ve been sending to spamd to make it more RFC-2822 compliant. Thanks!
Third, you can now specify a $mt_moderate threshold value. This means that if a comment submission is below the Spam threshold (defined in Spam Assassin), but above the $mt_moderate value, it will be moderated instead of being allowed all the way through to the blog.

#!/usr/bin/perl -w
package MT::Plugin::SpamAssassin;
use strict;
use lib '../lib';
use vars qw ($VERSION);
$VERSION='0.4';
# (CHANGE ME) what host is running spamd?
my $sa_spamd_host = q{localhost};
# (CHANGE ME) what port is spamd listening on?
my $sa_spamd_port = 783;
# (CHANGE ME) who is the owner of the blog?
my $mt_owner      = q{me@localhost.com};
# (CHANGE ME) what is the userid for SpamAssassin?
my $mt_userid     = q{me};
# (CHANGE ME) what is the moderate threshold?
my $mt_moderate   = 1.5;
use constant ACCEPT_RESPONSE => 1;
use constant DENY_RESPONSE   => 0;
use MT;
use MT::App::Comments;
use IO::Socket;
use Time::Local qw(timegm);
use POSIX;
eval{ require MT::Plugin };
unless ($@) {
    my $plugin = {
        name => qq{Spamassassin for Movable Type v$VERSION},
        description => qq{Spamassassin for Movable Type},
    };
    MT->add_plugin(new MT::Plugin($plugin));
    # tell MT that we want to be called to filter comments
    MT->add_callback('CommentFilter', 10, $plugin, \&sa_filter);
}
# sa_filter
#
# 'CommentFilter' that is called for each attempt to post a comment
# on your blog. We'll pass the incoming comment to spamd running on
# $sa_spamd_host:$sa_spamd_port. If spamd responds with an indication
# that the comment was spam, then we'll repond with DENY_RESPONSE.
# If spamd says it's no spam or we can't get a good connection to
# spamd, we'll respond with ACCEPT_RESPONSE
sub sa_filter {
    my($eh,$app,$comment)=@_;
    unless($comment->visible()) {
        return ACCEPT_RESPONSE;
    }
    #print STDERR "[".scalar(localtime())."] mt-spamassassin: " .
    #  join("/",$comment->author,$comment->email,$comment->url,$comment->ip) . "\n";
    my $now=rfc822_date();
    my $hostname=gethostbyaddr(inet_aton($comment->ip), AF_INET);
    my $message="From " . $comment->email . " " . $now . "\n" .
      "Received: from client ([" . $comment->ip . "] ".
      ($hostname?$hostname:$comment->ip) . ")" .
      " by " . $ENV{HTTP_HOST} . " via MovableType; " . $now . "\n" .
      "Message-id: <". sprintf("%x\$%x",time,rand(65535)) .
      "\@" . ($hostname?$hostname:sprintf("[%s]",$comment->ip)) . ">\n" .
      "From: " . $comment->author .
      " <" . $comment->email . ">\nDate: " . $now . "\n" .
      "Subject: MovableType comment\n" .
      "To: $mt_owner\n\n" .
      $comment->url . "\n".
      $comment->text;
    # make sure all lines end in "\r\n";
    $message =~ s/\r\n/\n/gs;
    $message =~ s/\r/\n/gs;
    $message =~ s/\n/\r\n/gs;
    # now send it off to Spamassassin
    my $socket=IO::Socket::INET->new(PeerAddr => $sa_spamd_host,
                                     PeerPort => $sa_spamd_port,
                                     Proto    => "tcp",
                                     Type     => SOCK_STREAM);
    # no socket - no spam check
    return ACCEPT_RESPONSE unless($socket);
    # create the CHECK message for spamd
    $message = "CHECK SPAMC/1.2\r\n" .
      "User: $mt_userid\r\n" .
      "Content-Length: ".length($message).
      "\r\n\r\n".
      $message;
    # print STDERR "[".scalar(localtime())."] sending to spamd:\n$message\n";
    # send it to spamd
    my $toSend=$message;
    while(length($toSend)) {
        my $written = $socket->send($toSend);
        unless(defined($written)) {
            # oh no, something went wrong 
            return ACCEPT_RESPONSE;
        }
        $toSend=substr($toSend,$written);
    }
    # close writing end of socket
    $socket->shutdown(1);
    # suck in response from SpamAssassin
    my $response;
    while(1) {
        my $buffer;
        unless(defined($socket->recv($buffer, 1024))) {
            return ACCEPT_RESPONSE;
        }
        last unless(length($buffer));
        $response .= $buffer;
    }
    # trim  whitespace off the beginning of the response
    $response =~ s/^\s*//;
    # check if it is really a SpamAssassin response
    return ACCEPT_RESPONSE unless ($response =~ /^spamd\/[\d\.]+/i);
    # now find "Spam: True|False ; score / limit" header
    return ACCEPT_RESPONSE
      unless ($response =~ /spam:\s*(\S+)\s*;\s*([\d\.]+)\s*\/\s*([\d\.]+)/is);
    my($flag,$score,$limit)=($1,$2,$3);
    #if($flag =~ /false/i) {
        #print STDERR "[".scalar(localtime())."] no spam:\n$message\n";
    #}
    print STDERR "[".scalar(localtime())."] spam $flag from " .
      join("/",$comment->author,$comment->email,$comment->ip) .
      ": score $score (limit $limit)\n";
    if($flag =~ /false/i) {
        if($score > $mt_moderate) {
            print STDERR "[".scalar(localtime())."] moderating comment\n";
            $comment->visible(0);
        }
        return ACCEPT_RESPONSE;
    }
    # log a line to the error_log
    return DENY_RESPONSE;
}
# rfc822_date
#
# generate a GMT date according to rfc822
sub rfc822_date {
    # offset in hours (from Mail::Sendmail)
    my $offset  = sprintf "%.1f", (timegm(localtime) - time) / 3600;
    my $minutes = sprintf "%02d", abs( $offset - int($offset) ) * 60;
    my $TZ  = sprintf("%+03d", int($offset)) . $minutes;
    return POSIX::strftime("%a, %d %b %Y %T $TZ",localtime(time()));
}
1;

it looks like some of your “Refer-A-Friend” participants are seeing the whole world as their friend and advertise your service in form of bulk-email to milions of people. This is rather annoying.
In reading through your “Refer-A-Friend” Terms and Conditions (go to the VistaPrint Help Section and select “Refer-a-Friend Terms and Conditions” in the right column) I can see under point 7 (quote):

7. If a Referring Customer provides a Personal Link to another person by email, the email must be created and distributed in a personal manner that is appropriate and customary for communications with friends and family members. Bulk email distribution, distribution to strangers, or any other promotion of a Personal Link in a manner that would constitute or appear to constitute unsolicited commercial email or “spam” under any applicable law or regulation is expressly prohibited and will be grounds for immediate termination of the Referring Customer’s account and deactivation of the Personal Link.

This makes me believe that you don’t like the way that your services are advertised via the message I receive every few days.
Would you be able to investigate whether those messages are being sent under the umbrella of bluk-mail and whether there is a way to stop the sender from bombarding us?

Here’s a small snapshot of the mails I received over the last few weeks:

What all those spam messages seem to have in common is that they refer to the bigdls.com and 4grtdlz.com domains. Here are just the last few ones (obviously not linked):

• http://rlmeeamsem.bigdls.com/icgkfet.html

• http://vtcggkczgc.bigdls.com/zfmnfwm.html
• http://loswwfszws.bigdls.com/pxkipqk.html
• http://zvbwwpbswb.bigdls.com/zfmwwpm.html
• http://eraeeuabea.bigdls.com/yqmvqqw.html
• http://zvbwwpbswb.bigdls.com/icfgebk.html
• http://tuxhhexvhx.bigdls.com/glktslk.html
• http://xbskkwscks.4grtdlz.com/kxjbmmj.html
• http://loswwfszws.4grtdlz.com/oanauoa.html

I followed the mind-blowing sequence of redirects for each one of them. Here’s just one example for the first link:


$ GET -x http://rlmeeamsem.bigdls.com/icgkfet.html
LWP::UserAgent::new: ()
LWP::UserAgent::request: ()
LWP::UserAgent::send_request: GET http://rlmeeamsem.bigdls.com/icgkfet.html
LWP::UserAgent::_need_proxy: Not proxied
LWP::Protocol::http::request: ()
LWP::Protocol::collect: read 302 bytes
LWP::UserAgent::request: Simple response: Found
LWP::UserAgent::request: ()
LWP::UserAgent::send_request: GET http://c.azjmp.com/az/ch.php?f=586&i=162
LWP::UserAgent::_need_proxy: Not proxied
LWP::Protocol::http::request: ()
LWP::Protocol::collect: read 110 bytes
LWP::UserAgent::request: Simple response: OK
<Script language = javascript> window.location.href='http://c.azjmp.com/az/ch.php?f=625&i=162&sub=';</script>

$ GET -x 'http://c.azjmp.com/az/ch.php?f=625&i=162&sub='
LWP::UserAgent::new: ()
LWP::UserAgent::request: ()
LWP::UserAgent::send_request: GET http://c.azjmp.com/az/ch.php?f=625&i=162&sub=
LWP::UserAgent::_need_proxy: Not proxied
LWP::Protocol::http::request: ()
LWP::Protocol::collect: read 120 bytes
LWP::UserAgent::request: Simple response: Found
LWP::UserAgent::request: ()
LWP::UserAgent::send_request: GET http://www.azoogleads.com/az/ch.php?f=625&i=162&sub=&pop=&aux=&bypass=
LWP::UserAgent::_need_proxy: Not proxied
LWP::Protocol::http::request: ()
LWP::Protocol::collect: read 412 bytes
LWP::UserAgent::request: Simple response: OK
<SCRIPT LANGUAGE="JavaScript">
function randwin() {
allwin=window.open("http://c.azjmp.com/az/ch.php?pop=0&f=548&i=162&sub=popup",'TheNewpop','toolbar=1,location=1,directories=1,status=1,menubar=1,scrollbars=1,resizable=1');
allwin.blur();
window.focus();
}
randwin()
</SCRIPT>
<Script language = javascript>
window.location.href='http://www.vistaprint.com/vp/gateway.asp?S=7979826309';
</script>

$

You can see that after this sequence of redirects (and a popup madness on the screen), we end up on your site with the URL: http://www.vistaprint.com/vp/gateway.asp?S=7979826309. – could it be that the “7979826309″ is a referral ID which allows you to track down the source of this spam-message and thus the spam-sender? All those other bigdls.com and 4grtdlz.com URLs above also end up on your site with the same referral ID.

Would it also be possible to apply your “Refer-A-Friend” Terms and Conditions to this particular friend and make sure that we are not receiving any more Spam from this source?

Regards
  Tobias